initHEADmaster

1 files changed, 47 insertions, 0 deletions

diff --git a/wmenu/protocols/meson.build b/wmenu/protocols/meson.build
new file mode 100755
index 0000000..5c9973d
--- /dev/null
+++ b/wmenu/protocols/meson.build
@@ -0,0 +1,47 @@
+wl_protocol_dir = wayland_protos.get_pkgconfig_variable('pkgdatadir')
+
+wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
+if wayland_scanner_dep.found()
+	wayland_scanner = find_program(
+		wayland_scanner_dep.get_pkgconfig_variable('wayland_scanner'),
+		native: true,
+	)
+else
+	wayland_scanner = find_program('wayland-scanner', native: true)
+endif
+
+protocols = [
+	[wl_protocol_dir, 'stable/xdg-shell/xdg-shell.xml'],
+	[wl_protocol_dir, 'staging/xdg-activation/xdg-activation-v1.xml'],
+	['wlr-layer-shell-unstable-v1.xml'],
+]
+
+wl_protos_src = []
+wl_protos_headers = []
+
+foreach p : protocols
+	xml = join_paths(p)
+	wl_protos_src += custom_target(
+		xml.underscorify() + '_protocol_c',
+		input: xml,
+		output: '@BASENAME@-protocol.c',
+		command: [wayland_scanner, 'private-code', '@INPUT@', '@OUTPUT@'],
+	)
+	wl_protos_headers += custom_target(
+		xml.underscorify() + '_client_h',
+		input: xml,
+		output: '@BASENAME@-client-protocol.h',
+		command: [wayland_scanner, 'client-header', '@INPUT@', '@OUTPUT@'],
+	)
+endforeach
+
+lib_client_protos = static_library(
+	'client_protos',
+	wl_protos_src + wl_protos_headers,
+	dependencies: wayland_client.partial_dependency(compile_args: true),
+)
+
+client_protos = declare_dependency(
+	link_with: lib_client_protos,
+	sources: wl_protos_headers,
+)